nix: import custom-nixpkgs

TODO.md

@@ -4,3 +4,4 @@
 - [x] `nix-darwin` appears to not pull in the overlays configuration (false-positive, I was fooled by OpenJDK on Darwin being aliased to Zulu)
 - [x] Restore `darwin-init` in programs.bash
 - [x] Restore server-specific Starship prompt
+- [ ] Re-expose packages.aarch64-darwin.macbook to let Garnix build binaries

flake.lock

@@ -147,35 +147,6 @@
         "type": "github"
       }
     },
-    "custom-nixpkgs": {
-      "inputs": {
-        "fenix": [
-          "fenix"
-        ],
-        "nix-github-actions": "nix-github-actions",
-        "nixpkgs": [
-          "nixpkgs"
-        ],
-        "rust-manifest": "rust-manifest",
-        "systems": [
-          "systems"
-        ]
-      },
-      "locked": {
-        "lastModified": 1709429023,
-        "narHash": "sha256-n3vHEHwB3JwozY7LFBPZl75V/Irkvo1VBCaWW4Elf68=",
-        "owner": "msfjarvis",
-        "repo": "custom-nixpkgs",
-        "rev": "860391aeb0a31d9c9f13d146f51585398bb25ffe",
-        "type": "github"
-      },
-      "original": {
-        "owner": "msfjarvis",
-        "ref": "main",
-        "repo": "custom-nixpkgs",
-        "type": "github"
-      }
-    },
     "darwin": {
       "inputs": {
         "nixpkgs": [
@@ -464,27 +435,6 @@
         "type": "github"
       }
     },
-    "nix-github-actions": {
-      "inputs": {
-        "nixpkgs": [
-          "custom-nixpkgs",
-          "nixpkgs"
-        ]
-      },
-      "locked": {
-        "lastModified": 1703863825,
-        "narHash": "sha256-rXwqjtwiGKJheXB43ybM8NwWB8rO2dSRrEqes0S7F5Y=",
-        "owner": "nix-community",
-        "repo": "nix-github-actions",
-        "rev": "5163432afc817cf8bd1f031418d1869e4c9d5547",
-        "type": "github"
-      },
-      "original": {
-        "owner": "nix-community",
-        "repo": "nix-github-actions",
-        "type": "github"
-      }
-    },
     "nix-index-database": {
       "inputs": {
         "nixpkgs": [
@@ -586,7 +536,6 @@
     },
     "root": {
       "inputs": {
-        "custom-nixpkgs": "custom-nixpkgs",
         "darwin": "darwin",
         "deploy-rs": "deploy-rs",
         "disko": "disko",
@@ -601,6 +550,7 @@
         "nixos-hardware": "nixos-hardware",
         "nixos-vscode-server": "nixos-vscode-server",
         "nixpkgs": "nixpkgs",
+        "rust-manifest": "rust-manifest",
         "snowfall-lib": "snowfall-lib",
         "sops-nix": "sops-nix",
         "srvos": "srvos",

flake.nix

@@ -9,6 +9,7 @@
       inherit inputs;
       src = ./.;
       snowfall = {
+        namespace = "jarvis";
         meta = {
           name = "msfjarvis-nix-configs";
           title = "msfjarvis' Nix configurations";
@@ -48,7 +49,6 @@
       ];
 
       overlays = with inputs; [
-        custom-nixpkgs.overlays.default
         fenix.overlays.default
         gphotos-cdp.overlays.default
         nix-vscode-extensions.overlays.default
@@ -75,7 +75,6 @@
       deploy = lib.mkDeploy {inherit (inputs) self;};
     }
     // {
-      packages.aarch64-darwin.macbook = inputs.self.darwinConfigurations.Harshs-MacBook-Pro.system;
       apps.x86_64-linux.default = inputs.deploy-rs.apps.x86_64-linux.default;
     };
 
@@ -97,11 +96,6 @@
 
     systems.url = "github:msfjarvis/flake-systems";
 
-    custom-nixpkgs.url = "github:msfjarvis/custom-nixpkgs/main";
-    custom-nixpkgs.inputs.nixpkgs.follows = "nixpkgs";
-    custom-nixpkgs.inputs.fenix.follows = "fenix";
-    custom-nixpkgs.inputs.systems.follows = "systems";
-
     darwin.url = "github:LnL7/nix-darwin/master";
     darwin.inputs.nixpkgs.follows = "nixpkgs";
 
@@ -146,6 +140,9 @@
     nixos-vscode-server.inputs.nixpkgs.follows = "nixpkgs";
     nixos-vscode-server.inputs.flake-utils.follows = "flake-utils";
 
+    rust-manifest.url = "https://static.rust-lang.org/dist/2023-10-22/channel-rust-nightly.toml";
+    rust-manifest.flake = false;
+
     snowfall-lib.url = "github:snowfallorg/lib/dev";
     snowfall-lib.inputs.flake-utils-plus.follows = "flake-utils-plus";
     snowfall-lib.inputs.nixpkgs.follows = "nixpkgs";

garnix.yaml

@@ -3,4 +3,4 @@ builds:
     - nixosConfigurations.crusty
     - nixosConfigurations.ryzenbox
     - nixosConfigurations.wailord
-    - packages.aarch64-darwin.*
+    - packages.x86_64-linux.*

modules/home/packages/default.nix

@@ -27,7 +27,7 @@
     shfmt
     sops
     tailscale
-    tea-dev
+    jarvis.tea-dev
     tmux
     unzip
     vivid

modules/nixos/desktop/android-dev.nix

@@ -13,12 +13,12 @@ in {
   };
   config = lib.mkIf cfg.android-dev.enable {
     users.users.msfjarvis.packages = with pkgs; [
-      adb-sync
-      adx
+      jarvis.adb-sync
+      jarvis.adx
       androidStudioPackages.stable
       androidStudioPackages.beta
       androidStudioPackages.canary
-      diffuse-bin
+      jarvis.diffuse-bin
       kotlin
     ];
 

modules/nixos/gphotos-cdp/default.nix

@@ -34,7 +34,7 @@ in {
       description = mdDoc "Group account under which gphotos-cdp runs.";
     };
 
-    package = mkPackageOptionMD pkgs "gphotos-cdp" {};
+    package = mkPackageOptionMD pkgs.jarvis "gphotos-cdp" {};
   };
 
   config = mkIf cfg.enable {

modules/nixos/rucksack/default.nix

@@ -32,7 +32,7 @@ in {
       description = mdDoc "Shell glob to filter files against to be eligible for moving";
     };
 
-    package = mkPackageOptionMD pkgs "rucksack" {};
+    package = mkPackageOptionMD pkgs.jarvis "rucksack" {};
 
     user = mkOption {
       type = types.str;
@@ -62,7 +62,7 @@ in {
         Environment = "PATH=${pkgs.coreutils}/bin:${pkgs.watchman}/bin";
       };
       script = ''
-        exec env RUCKSACK_CONFIG=${settingsFile} ${pkgs.rucksack}/bin/rucksack
+        exec env RUCKSACK_CONFIG=${settingsFile} ${lib.getExe cfg.package}
       '';
     };
 

packages/adb-sync/default.nix

@@ -0,0 +1,36 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) stdenvNoCC fetchFromGitHub;
+in
+  stdenvNoCC.mkDerivation rec {
+    pname = "adb-sync";
+    version = "1.0.0";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "adb-sync";
+      rev = "v${version}";
+      hash = "sha256-uoIueSbhml6lHgpI6OH1Y4cNeZzzTBS+PAPHf62xJzY=";
+    };
+
+    outputs = ["out"];
+
+    dontConfigure = true;
+    dontBuild = true;
+
+    installPhase = ''
+      install -m755 -D adb-sync $out/bin/adb-sync
+      install -m755 -D adb-channel $out/bin/adb-channel
+    '';
+
+    meta = with lib; {
+      homepage = "https://github.com/google/adb-sync";
+      description = "adb-sync is a tool to synchronize files between a PC and an Android device using the ADB (Android Debug Bridge)";
+      license = licenses.asl20;
+      platforms = platforms.all;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "adb-sync";
+    };
+  }

packages/adbtuifm/default.nix

@@ -0,0 +1,29 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) buildGoModule fetchFromGitHub;
+in
+  buildGoModule rec {
+    pname = "adbtuifm";
+    version = "0.5.8";
+
+    src = fetchFromGitHub {
+      owner = "darkhz";
+      repo = "adbtuifm";
+      rev = "v${version}";
+      hash = "sha256-TK93O9XwMrsrQT3EG0969HYMtYkK0a4PzG9FSTqHxAY=";
+    };
+
+    vendorHash = "sha256-voVoowjM90OGWXF4REEevO8XEzT7azRYiDay4bnGBks=";
+
+    ldflags = ["-s" "-w"];
+
+    meta = with lib; {
+      description = "A TUI File Manager for ADB";
+      homepage = "https://github.com/darkhz/adbtuifm";
+      license = licenses.mit;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "adbtuifm";
+    };
+  }

packages/adx/default.nix

@@ -0,0 +1,33 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) darwin fetchFromGitHub rustPlatform stdenv;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "adx";
+    version = "4.5.1";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "adx";
+      rev = "v${version}";
+      hash = "sha256-oDvi1bEARtki4pMRh99cgoEtGJ5S0e33yU9/lKZKRSs=";
+    };
+
+    cargoHash = "sha256-Y8quDq4dz9m92g0xrjb2KZ3BIlJwrH3CtCgY78wpCiA=";
+
+    useNextest = true;
+
+    buildInputs = lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.Security
+    ];
+
+    meta = with lib; {
+      description = "Rust tooling to poll Google Maven repository for updates to AndroidX artifacts";
+      homepage = "https://github.com/msfjarvis/adx";
+      license = with licenses; [asl20 mit];
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "adx";
+    };
+  }

packages/clipboard-substitutor/default.nix

@@ -0,0 +1,38 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) darwin fetchFromGitHub rustPlatform stdenv xorg;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "clipboard-substitutor";
+    version = "0.7.7";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "clipboard-substitutor";
+      rev = "v${version}";
+      hash = "sha256-WSvSDZJ2SOtE68BHv7IINieVgblfWdpNrurFH7+83aI=";
+    };
+
+    buildFeatures = lib.optionals stdenv.isLinux ["journald"];
+    cargoHash = "sha256-iYSR7dXrEU0VasCzmkA0lSW6Wj5t8o3uF4oVIc8chy8=";
+
+    useNextest = true;
+
+    buildInputs =
+      lib.optionals stdenv.isDarwin [
+        darwin.apple_sdk.frameworks.AppKit
+      ]
+      ++ lib.optionals stdenv.isLinux [
+        xorg.libxcb
+      ];
+
+    meta = with lib; {
+      description = "CLI to listen to clipboard events and perform operations on the copied text";
+      homepage = "https://github.com/msfjarvis/clipboard-substitutor";
+      license = with licenses; [asl20 mit];
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "clipboard-substitutor";
+    };
+  }

packages/diffuse-bin/default.nix

@@ -0,0 +1,34 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) stdenvNoCC fetchurl;
+in
+  stdenvNoCC.mkDerivation rec {
+    pname = "diffuse-bin";
+    version = "0.1.0";
+    src = fetchurl {
+      url = "https://github.com/JakeWharton/diffuse/releases/download/${version}/diffuse-${version}-binary.jar";
+      hash = "sha256-YNYZNzxGpdBrgSbB1h4K3Bi3Lyy7kkXvkg0zh+RLhs8=";
+    };
+
+    dontUnpack = true;
+    dontBuild = true;
+    dontConfigure = true;
+
+    installPhase = ''
+      mkdir -p $out/bin
+      printf "#!/bin/sh\n\nexec java \$JAVA_OPTS -jar \$0 \"\$@\"\n" > $out/bin/diffuse
+      cat $src >> $out/bin/diffuse
+      chmod +x $out/bin/diffuse
+    '';
+
+    meta = with lib; {
+      description = "Diffuse is a tool for diffing APKs, AABs, AARs, and JARs";
+      homepage = "https://github.com/jakewharton/diffuse";
+      license = licenses.asl20;
+      platforms = platforms.all;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "diffuse";
+    };
+  }

packages/gdrive/default.nix

@@ -0,0 +1,29 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) buildGoModule fetchFromGitHub;
+in
+  buildGoModule rec {
+    pname = "gdrive";
+    version = "3.0.13";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "gdrive";
+      rev = "v${version}";
+      hash = "sha256-FFNgMV3gPQ2p1ilYK+t10UgcNF/knO/PVM3Zw/VSSGw=";
+    };
+
+    vendorHash = "sha256-WibiLYMeWR63Q8lu287jeczT0n0/lh6T8PfOH7eJh8Q=";
+
+    ldflags = ["-s" "-w"];
+
+    meta = with lib; {
+      description = "Google Drive CLI Client";
+      homepage = "https://github.com/msfjarvis/gdrive";
+      license = licenses.mit;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "gdrive";
+    };
+  }

packages/gitice/default.nix

@@ -0,0 +1,38 @@
+{
+  pkgs,
+  lib,
+  inputs,
+}: let
+  inherit (pkgs) fetchFromGitHub makeRustPlatform;
+  inherit (inputs) rust-manifest;
+  inherit ((import inputs.fenix {inherit pkgs;})) fromManifestFile;
+
+  toolchain = (fromManifestFile rust-manifest).minimalToolchain;
+in
+  (makeRustPlatform {
+    cargo = toolchain;
+    rustc = toolchain;
+  })
+  .buildRustPackage rec {
+    pname = "gitice";
+    version = "2.0.4";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "gitice";
+      rev = "v${version}";
+      hash = "sha256-GsB+2yRClow6VCPeXTdsJqXjjvIKlyg6uKK6jgVe7P8=";
+    };
+
+    cargoHash = "sha256-uAvXo/NVe+tUDV32RFPmJDaXriGiAX/jyjtgIp2PSrQ=";
+
+    useNextest = true;
+
+    meta = with lib; {
+      description = "Snapshot your local git repositories for easy restoration";
+      homepage = "https://github.com/msfjarvis/gitice";
+      license = with licenses; [asl20 mit];
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "gitice";
+    };
+  }

packages/gphotos-cdp/default.nix

@@ -0,0 +1,29 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) buildGoModule fetchFromGitHub;
+in
+  buildGoModule rec {
+    pname = "gphotos-cdp";
+    version = "unstable-2024-01-28";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "gphotos-cdp";
+      rev = "4262092a2fe585f4b66bd50bd4c235e8f24824f6";
+      hash = "sha256-xLCldbD37JEDQTwFSUqiEOM09vH+KaB/I8O3WoNqR6A=";
+    };
+
+    vendorHash = "sha256-FzGDVMKzAjISb4P7/vBIBTbBWpyAUnR26gXcvUWnjHw=";
+
+    ldflags = ["-s" "-w"];
+
+    meta = with lib; {
+      description = "This program uses the Chrome DevTools Protocol to drive a Chrome session that downloads your photos stored in Google Photos";
+      homepage = "https://github.com/msfjarvis/gphotos-cdp";
+      license = licenses.asl20;
+      maintainers = with maintainers; [];
+      mainProgram = "gphotos-cdp";
+    };
+  }

packages/hcctl/default.nix

@@ -0,0 +1,35 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) darwin fetchFromGitHub rustPlatform stdenv;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "hcctl";
+    version = "2.0.8";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "healthchecks-rs";
+      rev = "hcctl-v${version}";
+      hash = "sha256-A83pzY+c4kz59tHEc6hRd0Zp8Uj96KdrenD9RDWwavQ=";
+    };
+
+    buildInputs =
+      lib.optionals stdenv.isDarwin
+      [darwin.apple_sdk.frameworks.Security];
+
+    buildAndTestSubdir = "hcctl";
+
+    cargoHash = "sha256-v8mpH1akao35P8ePFTFLBidkPW+vzsaMg4h51TudYMM=";
+
+    useNextest = true;
+
+    meta = with lib; {
+      description = "Simple CLI tool to keep a track of your https://healthchecks.io account";
+      homepage = "https://msfjarvis.dev/g/healthchecks-rs";
+      license = with licenses; [asl20 mit];
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "hcctl";
+    };
+  }

packages/healthchecks-monitor/default.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  stdenv,
+  darwin,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "healthchecks-monitor";
+  version = "3.0.6";
+
+  src = fetchFromGitHub {
+    owner = "msfjarvis";
+    repo = "healthchecks-rs";
+    rev = "healthchecks-monitor-v${version}";
+    hash = "sha256-A83pzY+c4kz59tHEc6hRd0Zp8Uj96KdrenD9RDWwavQ=";
+  };
+
+  buildInputs =
+    lib.optionals stdenv.isDarwin
+    [darwin.apple_sdk.frameworks.Security];
+
+  buildAndTestSubdir = "monitor";
+
+  cargoHash = "sha256-2+dV0mIvbDqXqRfNCBhqUVRYhpcPB2oxD67GBkEDW48=";
+
+  useNextest = true;
+
+  meta = with lib; {
+    description = "CLI tool to run shell jobs and report status to https://healthchecks.io";
+    homepage = "https://msfjarvis.dev/g/healthchecks-rs";
+    license = with licenses; [asl20 mit];
+    maintainers = with maintainers; [msfjarvis];
+    mainProgram = "healthchecks-monitor";
+  };
+}

packages/katbin/default.nix

@@ -0,0 +1,34 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) darwin fetchFromGitHub rustPlatform stdenv;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "katbin-cli";
+    version = "1.3.15";
+
+    src = fetchFromGitHub {
+      owner = "SphericalKat";
+      repo = "katbin-cli";
+      rev = "v${version}";
+      hash = "sha256-MGYzh5OBNPy2e+RVSppA7a1+cixyaxMwXeOuRV9aFmg=";
+    };
+
+    cargoHash = "sha256-Wbcw2eMD2OtL7qp8XL2Ri60yuyisiQRatY77egtEKlg=";
+
+    doCheck = false;
+
+    buildInputs = lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.Security
+    ];
+
+    meta = with lib; {
+      description = "A CLI for katbin";
+      homepage = "https://github.com/SphericalKat/katbin-cli";
+      changelog = "https://github.com/SphericalKat/katbin-cli/blob/${src.rev}/CHANGELOG.md";
+      license = with licenses; [asl20 mit];
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "katbin";
+    };
+  }

packages/linkleaner/default.nix

@@ -0,0 +1,44 @@
+{
+  pkgs,
+  lib,
+  inputs,
+}: let
+  inherit (pkgs) fetchFromGitHub makeRustPlatform stdenv darwin;
+  inherit (inputs) rust-manifest;
+  inherit ((import inputs.fenix {inherit pkgs;})) fromManifestFile;
+
+  toolchain = (fromManifestFile rust-manifest).minimalToolchain;
+in
+  (makeRustPlatform {
+    cargo = toolchain;
+    rustc = toolchain;
+  })
+  .buildRustPackage rec {
+    pname = "linkleaner";
+    version = "1.8.3";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "linkleaner";
+      rev = "v${version}";
+      hash = "sha256-lxKMmSySY5EbnK7GccoFBcQGaqkuir95nVOJkd4L08s=";
+    };
+
+    buildInputs = lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.Security
+      darwin.apple_sdk.frameworks.SystemConfiguration
+    ];
+
+    cargoHash = "sha256-9oAC+B3uboNyIvk/C5WLlPZT/d4FgSKrGIMw40cbxEE=";
+
+    useNextest = true;
+
+    meta = with lib; {
+      description = "A Telegram bot with an identity crisis";
+      homepage = "https://msfjarvis.dev/g/linkleaner/";
+      license = licenses.mit;
+      platforms = platforms.all;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "linkleaner";
+    };
+  }

packages/monocraft-nerdfonts/default.nix

@@ -0,0 +1,31 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) stdenvNoCC fetchurl;
+in
+  stdenvNoCC.mkDerivation rec {
+    pname = "monocraft-nerdfonts";
+    version = "3.0";
+    src = fetchurl {
+      url = "https://github.com/IdreesInc/Monocraft/releases/download/v${version}/Monocraft-nerd-fonts-patched.ttf";
+      hash = "sha256-QxMp8UwcRjWySNHWoNeX2sX9teZ4+tCFj+DG41azsXw=";
+    };
+
+    dontUnpack = true;
+    dontBuild = true;
+    dontConfigure = true;
+
+    installPhase = ''
+      mkdir -p $out/share/fonts/truetype/
+      cat $src > $out/share/fonts/truetype/Monocraft-nerdfonts.ttf
+    '';
+
+    meta = with lib; {
+      description = "A monospaced programming font inspired by the Minecraft typeface";
+      homepage = "https://github.com/IdreesInc/Monocraft";
+      license = licenses.ofl;
+      platforms = platforms.all;
+      maintainers = with maintainers; [msfjarvis];
+    };
+  }

packages/patreon-dl/default.nix

@@ -0,0 +1,29 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) buildGoModule fetchFromGitHub;
+in
+  buildGoModule {
+    pname = "patreon-dl";
+    version = "1.0.2";
+
+    src = fetchFromGitHub {
+      owner = "PrivateGER";
+      repo = "patreon-dl";
+      rev = "1db8b378af8c889d841036b2eaf6cb2461011ee8";
+      hash = "sha256-CiMR6mb6PKj9enO4nDm959MxdQNo0UMo5nif6x37UBE=";
+    };
+
+    vendorHash = "sha256-6Y8SmgH5SFvkw3YQh8SlSktJsctped8as1FCdIc4FQc=";
+
+    ldflags = ["-s" "-w"];
+
+    meta = with lib; {
+      description = "A Patreon Image Downloader";
+      homepage = "https://github.com/PrivateGER/patreon-dl";
+      license = licenses.unlicense;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "patreon-dl";
+    };
+  }

packages/pidcat/default.nix

@@ -0,0 +1,38 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) fetchFromGitHub installShellFiles stdenvNoCC;
+in
+  stdenvNoCC.mkDerivation rec {
+    pname = "pidcat";
+    version = "2.2.0";
+    # I already fixed it in the source
+    dontPatchShebangs = 1;
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "pidcat";
+      rev = "v${version}";
+      hash = "sha256-VOIND2CzWo+LV84C+FbTC0r3FqY7VpBaWn95IKTYFT8=";
+    };
+
+    nativeBuildInputs = [installShellFiles];
+
+    postInstall = ''
+      installShellCompletion --bash bash_completion.d/pidcat
+    '';
+
+    installPhase = ''
+      install -m755 -D pidcat.py $out/bin/pidcat
+    '';
+
+    meta = with lib; {
+      homepage = "https://github.com/JakeWharton/pidcat";
+      description = "pidcat - colored logcat script";
+      license = licenses.asl20;
+      platforms = platforms.all;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "pidcat";
+    };
+  }

packages/rucksack/default.nix

@@ -0,0 +1,30 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) fetchFromGitHub rustPlatform stdenv;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "rucksack";
+    version = "1.0.8";
+
+    src = fetchFromGitHub {
+      owner = "msfjarvis";
+      repo = "rucksack";
+      rev = "v${version}";
+      hash = "sha256-MpDfvNdD/tdOZ3sIoGRAC8hOFimylvWy/MuxZgZqU7M=";
+    };
+
+    buildFeatures = lib.optionals stdenv.isLinux ["journald"];
+    cargoHash = "sha256-lv2KcEQqERa+brQXVWwjaeLdqPDTa4ZLVwQZo+jqv0Y=";
+
+    useNextest = true;
+
+    meta = with lib; {
+      description = "Simple CLI tool to watch directories and move their files to a single dumping ground";
+      homepage = "https://github.com/msfjarvis/rucksack";
+      license = with licenses; [asl20 mit];
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "rucksack";
+    };
+  }

packages/tea-dev/default.nix

@@ -0,0 +1,33 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) buildGoModule fetchFromGitea;
+in
+  buildGoModule rec {
+    pname = "tea";
+    version = "unstable-2023-12-26";
+
+    src = fetchFromGitea {
+      domain = "gitea.com";
+      owner = "gitea";
+      repo = "tea";
+      rev = "fb4eb8be9cc2e2cd6081cb458d907742c5583c76";
+      hash = "sha256-QorZO6HR+gHWHe2tMlh9UB1MShoU+JzCh73ZZ5n4IXM=";
+    };
+
+    vendorHash = "sha256-yZssgbQEuoHv5fRJCM0wsniguUxorJT0yFYUlsp+wqM=";
+
+    ldflags = [
+      "-s"
+      "-w"
+      "-X=main.Version=${version}"
+    ];
+
+    meta = with lib; {
+      description = "A command line tool to interact with Gitea servers";
+      homepage = "https://gitea.com/gitea/tea";
+      license = licenses.mit;
+      maintainers = with maintainers; [];
+    };
+  }

packages/when/default.nix

@@ -0,0 +1,31 @@
+{
+  pkgs,
+  lib,
+}: let
+  inherit (pkgs) fetchFromGitHub rustPlatform;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "when";
+    version = "0.4.0";
+
+    src = fetchFromGitHub {
+      owner = "mitsuhiko";
+      repo = "when";
+      rev = version;
+      hash = "sha256-JvnvGD14VOXu0+xVMF4aQLvgOFLxNsebCSgKZLycHUw=";
+      fetchSubmodules = true;
+    };
+
+    cargoHash = "sha256-HhxAk5pLOpn2cRDoPkrxyV27n6IGAI2vkep9j3o275I=";
+
+    useNextest = true;
+
+    meta = with lib; {
+      description = "Timezones from the command line";
+      homepage = "https://github.com/mitsuhiko/when";
+      changelog = "https://github.com/mitsuhiko/when/blob/${src.rev}/CHANGELOG.md";
+      license = licenses.asl20;
+      maintainers = with maintainers; [msfjarvis];
+      mainProgram = "when";
+    };
+  }

systems/aarch64-darwin/Harshs-MacBook-Pro/default.nix

@@ -9,19 +9,19 @@
   };
 
   environment.systemPackages = with pkgs; [
-    adx
+    jarvis.adx
     awscli2
     coreutils
-    diffuse-bin
-    gdrive
+    jarvis.diffuse-bin
+    jarvis.gdrive
     git-absorb
     hub
-    katbin
+    jarvis.katbin
     maestro
     ninja
     openssh
     openssl
-    pidcat
+    jarvis.pidcat
     scrcpy
   ];
 

systems/x86_64-linux/ryzenbox/default.nix

@@ -83,18 +83,18 @@
       })
       fzf
       gallery-dl
-      gdrive
+      jarvis.gdrive
       git-crypt
       helix
       nerdfonts
-      katbin
+      jarvis.katbin
       kondo
       maestro
       megatools
       mullvad
       mullvad-vpn
-      patreon-dl
-      pidcat
+      jarvis.patreon-dl
+      jarvis.pidcat
       psst
       (python311.withPackages (ps: with ps; [beautifulsoup4 black requests virtualenv]))
       scrcpy